Passer au contenu principal
Adaptive Insights
Knowledge and Support - Adaptive Insights

Exemples de calculs de personnel, avantages sociaux

Donne des exemples détaillés des formules de prestations utilisées le plus souvent.

Exemple 1 : Calcul du 401k (Contributions supplémentaires de retraite)

Pour les calculs du 401k, la plupart des sociétés utilisent soit une hypothèse de contributions de contrepartie sur la base d’un taux fixe, soit une contribution de contrepartie à taux fixe mais plafonné chaque année, pour planifier leurs frais de personnel.

401k, Taux fixe

  • Créez les comptes d’hypothèses globales suivants :
Nom de l’hypothèse Code de l’hypothèse Type de compte
401(k), Contribution de contrepartie fixe 401K_FLAT_Match Pour cent

Formule

Nom du compte Code du compte Type de compte Formule
401(k), Contribution employé 401kEmployeeElection Modélisé - périodique - Devise

ASSUM.401K_Flat_Match*
ROW.TaxableComp

401k, Contribution de contrepartie avec maximum

  • Créez les comptes d’hypothèses globales suivants :
Nom de l’hypothèse Code de l’hypothèse Type de compte Afficher comme
401(k) Max 401K_Max Périodique - Moyenne Nombre
401(k) 100 % des premiers x % Match_100Perc Périodique - Moyenne Pour cent
401(k) 50 % des x % suivants Match_50Perc Périodique - Moyenne Pour cent
  • Vérifiez que ces comptes ont les Paramètres de compte suivants :

    • Cumul temps = Moyenne des valeurs cumulées
    • Superposition des données réelles = Pas de données réelles pour le compte (Montrer les données du plan)
  • Les comptes modélisés requis incluent :
Nom du compte Code du compte Type de compte Afficher comme
Comp taxable TaxableComp Modélisé - périodique Devise

Formules

Nom du compte Code du compte Type de compte  

401(k), Contribution de contrepartie
100 % - Cumulative

Comp_Match_100 Modélisé - Périodique - Devise  

Formule

IFF(month(this)=1,ROW.TaxableComp*ASSUM.Match_100Perc, ROW.Comp_Match_100[time=this-1] + ROW.TaxableComp *ASSUM.Match_100Perc)

 

401(k), Contribution de contrepartie
50 % - Cumulative

Comp_Match_50 Modélisé - Périodique - Devise

 

Formule

IFF(month(this)=1,ROW.TaxableComp*DIVF(ASSUM.Match_50Perc,2), ROW.Comp_Match_50[time=this-1] + ROW.TaxableComp *DIVF(ASSUM.Match_50Perc,2))

401(k), Contribution de contrepartie
Total - Cumulatif
Comp_Match_Total Modélisé - Périodique - Devise

 

Formule

ROW.Comp_Match_100+ROW.Comp_Match_50

 

401k, Frais 401k_Expense Modélisé - Périodique - Devise  

Formule

IFF(ROW.Comp_Match_Total<=ASSUM.401k_Max, (ROW.TaxableComp*ASSUM.Match_100Perc)+(ROW.TaxableComp*divf(ASSUM.Match_50Perc,2)), IFF(ROW.Comp_Match_Total>ASSUM.401k_Max and ROW.Comp_Match_Total[time=this-1]<=ASSUM.401k_Max, ASSUM.401k_Max-ROW.Comp_Match_Total[time=this-1],0))

Exemple 2 : Prestations médicales, dentaires et soins de la vue

La plupart des sociétés souhaiteront planifier les Prestations médicales, dentaires et les soins de la vue en fonction des choix de l’employé’, avec la possibilité de gérer/tenir à jour des taux séparés pour chaque.

Pour commencer à établir une dimension de Prestation. Conservez les paramètres standard. Vérifiez que Dimension Liste est sélectionnée, mais aussi que Appliquer aux niveaux, Importation de données crée automatiquement les valeurs de dimension et Garder trié ne sont pas sélectionnés.

Au sein de la dimension, créez les valeurs de dimension suivantes :

  1. Employé seulement      
  2. Employé + Conjoint
  3. Employé + Enfant
  4. Employé + Famille

Créez les comptes d’hypothèses globales suivants :

  • Créez une feuille cube attribuée à l’utilisateur, disponible au Niveau supérieur (seulement) et créez trois comptes cube standard :
Nom du compte Code du compte Type de compte Afficher comme
Taux médical Medical Périodique Devise
Taux dentaire Dental Périodique Devise
Taux Soins de la vue Vision Périodique Devise
  • Vérifiez que ces comptes ont les Paramètres de compte suivants :

    • Cumul temps = Moyenne des valeurs cumulées
    • Cumul niveau = Moyenne des valeurs non vides cumulées
    • Superposition des données réelles = Pas de données réelles pour le compte (Montrer les données du plan)
    • Afficher comme = Devise
    • Confidentialité des données + La valeur du compte est publique à tous les niveaux

Une fois que les comptes cubes sont prêts, ajoutez la dimension Prestations à la feuille cube.

Formules

Les tableaux de correspondance mensuels nécessaires sont :

Nom du compte Code du compte Colonne Valeur saisie
Éligible pour prestations Benefits_Eligible Type d’employé - Sélecteur de texte Peupler 1 dans toutes les combinaisons pertinentes

Établissez maintenant les comptes calculés suivants au sein de la feuille modélisée Personnel :

Nom du compte Code du compte Type de compte Formule
Frais médicaux Medical_Expense Modélisé - Périodique - Devise

ACCT.Beneft_Rates.Medical[level=Top Level(-), Benefit=this]*Row.Headcount*Row.Benefits_Eligible

Frais dentaires Dental_Expense Modélisé - Périodique - Devise

ACCT.Beneft_Rates.Dental[level=Top Level(-), Benefit=this]*Row.Headcount*Row.Benefits_Eligible

Frais Soins de vue Vision_Expense Modélisé - Périodique - Devise

ACCT.Beneft_Rates.Vision[level=Top Level(-),
Benefit=this]*Row.Headcount*Row.Benefits_Eligible

Exemple 3 : Assurance-vie

La plupart des sociétés ont un plan d’assurance-vie à taux fixe pour X euros de prestation.

  • Créez les comptes d’hypothèses globales suivants :
Nom de l’hypothèse Code de l’hypothèse Type de compte
Life_Rate Taux d’assurance-vie par X€ de prestation Nombre
Life_per_Dollar € (par) à appliquer au taux Nombre
Life_Multiplier Multiplicateur vie (Revenus annuels) Nombre
Life_Max_Benefit Prestation max vie Nombre
  • Vérifiez que ces comptes ont les Paramètres de compte suivants :

    • Cumul temps = Moyenne des valeurs cumulées
    • Superposition des données réelles = Pas de données réelles pour le compte (Montrer les données du plan)

Formule

Nom de l’hypothèse Code de l’hypothèse Type de compte  
Assurance-vie Life_Insurance Modélisé - Périodique - Devise  

Formule

IFF(DIV(ASSUM.Life_Max_Benefit,ASSUM.Life_per_Dollar)*
ASSUM.Life_Rate> DIV(((ROW.Headcount*ROW.Salary*ASSUM.Life_Multiplier)),ASSUM.Life_per_Dollar)*
ASSUM.Life_Rate,DIV(((ROW.Headcount*ROW.Salary)*
ASSUM.Life_Multiplier),ASSUM.Life_per_Dollar)*
ASSUM.Life_Rate,div(ASSUM.Life_Max_Benefit,ASSUM.Life_per_Dollar)*ASSUM.Life_Rate)*
Row.Benefits_Eligible

Exemple 4 : Assurance invalidité long terme/court terme (LTD/STD)

La plupart des sociétés paient pour l’assurance invalidité de leurs employés sur la base d’un taux par euros de prestation. 

  • Créez les comptes d’hypothèses globales suivants :
Nom de l’hypothèse Code de l’hypothèse Type de compte Afficher comme
Taux par 100 € LTD_RatePer100 Périodique - Moyenne Nombre
Taux par 10 € STD_RatePer10 Périodique - Moyenne Nombre
  • Vérifiez que ces comptes ont les Paramètres de compte suivants :

    • Cumul temps = Moyenne des valeurs cumulées
    • Superposition des données réelles = Pas de données réelles pour le compte (Montrer les données du plan)

Formules

Nom de compte Code de compte Type de compte Formules
Frais LTD LTD_Expense Modélisé - Périodique - Devise

DIVF(ROW.Salary,100) * ASSUM.LTD_RatePer100 * Row.Benefits_Eligible

Frais STD STD_Expense Modélisé - Périodique - Devise

DIVF(ROW.Salary,10) * ASSUM.STD_RatePer10 * Row.Benefits_Eligible