Passer au contenu principal
Adaptive Insights
Knowledge and Support - Adaptive Insights

Pas à pas pour la formule du taux de rémunération

Donne un exemple de formule d’augmentation du taux de rémunération comprenant une description pas à pas des instructions composant la formule.

Cette rubrique donne des détails sur un calcul du taux de rémunération utilisé dans une feuille modélisée Personnel. La formule initiale pose comme hypothèse qu’un employé recevra une augmentation annuelle ou bien durant un Mois d’augmentation spécifique, ou à la date de leur anniversaire. La rubrique contient aussi des alternatives à cette formule.

Dans cet exemple, la formule Taux de rémunération référence des valeurs saisies dans les hypothèses Mois d’augmentation et Augmentation Pct (percent)1.

Il faut comprendre certaines choses sur le calcul du Taux de rémunération : 

  • La colonne Taux de rémunération est un élément (cumulatif) du Solde initial, planifié sur la base d’un delta mensuel, ce qui veut dire que les données saisies dans la planification sont ensuite propagées dans toutes les périodes de la version. Les calculs que vous faites sur l’élément s’ajouteront au solde du mois précédent sur le compte.
  • La syntaxe pour les instructions IF dans Adaptive Planning diffère de celle d’Excel :
    • Adaptive Planning exemple :  if(ACCT.A6=1 and ACCT.B6=0,X,0)
    • Exemple Excel : if(and(A6=1, B6=0),X,0)
  • Il y a trois références de base au temps dans le calcul du Taux de rémunération. Chaque référence assigne un nombre à chaque mois pour la version et peut être utilisée pour comparer une colonne de dates au nombre assigné au mois dans la version.  
    • Mois : Chaque mois se voit assigner un nombre (1-12) suivant l’année civile, qui est propagé à travers la version. 
    • Fiscalmonth : Chaque mois se voit assigner un nombre (1-12) suivant l’année fiscale, qui est propagé à travers la version.
    • Versionmonth : Chaque mois se voit assigner un nombre. Le premier mois de la version est 0. Les nombres continuent dans le temps (sans se répéter). Les nombres positifs indiquent les mois à venir. Les nombres négatifs (-) indiquent les mois passés. 

Le calcul du Taux de rémunération est :

IF((VersionMonth(this) > 0) AND ROW.Headcount>0 AND (((VersionMonth(this) - VersionMonth(ROW.StartDate) > 1) AND ASSUM.RaiseMonth = 0 AND FiscalMonth(this) = FiscalMonth(ROW.StartDate)) OR (ASSUM.RaiseMonth = Month(this))), ROW.PayRate[time=THIS-1]*ASSUM.RaisePct, 0)

Le tableau suivant donne des détails sur chaque instruction du calcul :

Instruction Description
VersionMonth(this)>0 Cette instruction vérifie que le numéro de mois assigné pendant toute période dans votre version est supérieur au premier mois de la version. Ceci évite l’attribution d’une augmentation durant le premier mois de la version. Il est présumé que vous ayez saisi le salaire d’un employé pendant le premier mois comme leur salaire initial.
ROW.Headcount>0 Vérifie que l’employé est bien employé avant d’appliquer l’augmentation du taux de rémunération. Effectif est basé sur le salaire initial de l’employé et la colonne date finale. Il s’agit d’une gâchette binaire qui peut avoir pour résultat 0 ou 1 pour indiquer que l’employé est employé (ou pas) durant chaque période.
VersionMonth(this)-VersionMonth(ROW.StartDate)>1 Vérifie chaque mois où la formule est utilisée pour assurer qu’une augmentation de salaire n’est pas appliquée avant la date de début d’un employé. La VersionMonth assignée à chaque période est comparée à la VersionMonth unique assignée à la date de début de l’employé. Si la différence est supérieure à un (la période se passe après la date de début de l’employé), l’employé peut recevoir une augmentation, si toutes les autres instructions AND  sont validées.
ASSUM.RaiseMonth = 0 Vérifie chaque mois que l’hypothèse RaiseMonth est 0. Pour les augmentations d’anniversaire, il faut que le mois d’augmentation soit zéro.
FiscalMonth(this)=FiscalMonth(ROW.StartDate) Vérifie chaque FiscalMonth et le compare au FiscalMonth  assigné à la date de début de l’employé. Par exemple : si la date de début de l’employé est 12.8.2016et que le calendrier fiscal de la société’ correspond au calendrier civil, le mois assigné à FiscalMonth(ROW.StartDate) sera 8. En janvier de chaque année, FiscalMonth(this) donne un 1. Février donne un 2, etc. Cette phrase n’est vraie que lorsque le FiscalMonth est le même que le FiscalMonth de la date de début d’un employé. C’est de cette façon qu’il est possible de calculer, d’année en année, quelque chose en fonction d’une date d’anniversaire.
ASSUM.RaiseMonth = Month(this)

Vérifie que le nombre saisi pour l’hypothèse RaiseMonth correspond au nombre du mois courant. Par exemple : si vous voulez que l’augmentation prenne effet en avril 2017, mettez un 4 dans l’hypothèse RaiseMonth en avril 2017.

ROW.PayRate[time=THIS-1]*ASSUM.RaisePct

Définit la clause True (Vrai). Si les instructions précédentes sont vraies (toutes les instructions AND et une des instructions OR ), alors toutes les conditions IF sont satisfaites et l’augmentation (ASSUM.PaisePct) est appliquée.

La formule PayRate  référence la période précédente [time=THIS-1], pas la période courante. Pour les raisons suivantes :

  • Le calcul de PayRate est un élément du solde initial. Il reportera le solde saisi dans la colonne de la planification vers l’avant (mois précédent plus). S’il existe une formule dans l’élément de solde initial comme celle décrite ici, une addition au mois précédent sera calculée. 
  • Dans la mesure où l’élément de solde initial reporte automatiquement le solde et lui ajoute tout nouveau calcul, il influencera aussi tout ce qui a été évalué dans le mois courant. Donc, pour éviter toute référence circulaire, l’augmentation est basée sur le solde du taux de rémunération du mois précédent.
0 Définit la clause False (Faux). Quand une (ou plusieurs) instructions IF ne sont pas validées, l’augmentation est 0 et rien n’est ajouté au solde.

Si on la lisait comme une phrase, cette formule serait :

"Si ce mois est inclus dans cette version du budget et que l’employé est employé, et que la période est postérieure à la date de début de l’employé, et la valeur de l’hypothèse est zéro, et le mois courant est le même que la date de début de l’employé, ou le mois courant correspond à la valeur de l’hypothèse du mois courant, alors donnez une augmentation. Sinon, ne donnez pas d’augmentation."  

Options alternatives pour les Augmentations

Les organisations ne donnent typiquement pas une augmentation durant le mois de l’augmentation ou à la date d’anniversaire. La plupart des organisations utilisent une version plus simple de ce calcul d’ajout. 

Option 1 : Donnez les augmentations durant le mois d’augmentation. La formule est :

if(VersionMonth(this)>0 and ROW.Headcount>0 and VersionMonth(this)-VersionMonth(ROW.StartDate)>1 and ASSUM.RaiseMonth=fiscalmonth(this), ROW.PayRate[time=THIS-1]*ASSUM.RaisePct, 0

Les modifications incluent :

Instruction Description
ROW.Headcount>0 Comme auparavant, le Headcount (Effectifs) doit être supérieur à zéro plutôt qu’égal à 1. Ceci permet au calcul de fonctionner pour toutes les rangées d’un employé fractionnel, qui pourrait avoir une valeur inférieure à un effectif dans une rangée.
ASSUM.RaiseMonth=FiscalMonth(this)  Le RaiseMonth (Mois d’augmentation) est comparé au mois fiscal de la société. Ceci permet à la personne qui crée les hypothèses de penser en termes d’année fiscale de la société’ plutôt que de les forcer à utiliser une année civile.
fiscalmonth(this) = fiscalmonth(ROW.StartDate)) or (ASSUM. RaiseMonth = Month(this)  Il n’y a pas d’instruction OR (OU) pour la date d’anniversaire. L’augmentation n’est appliquée qu’au mois où elle est accordée. 

 

Option 2 : Appliquez les augmentations à la date d’anniversaire.  La formule est :

if(VersionMonth(this)> 0 AND ROW.Headcount>0 AND VersionMonth(this)-VersionMonth(ROW.StartDate)> 1 AND FiscalMonth(this)=FiscalMonth(ROW.StartDate), ROW.PayRate[time=THIS-1]*ASSUM.RaisePct, 0)

Pour d’autres options Taux de rémunération, veuillez vous référer aux Exemples de formules - Personnel, Calculs de taux de rémunération.